[📚정보] [GMS2] 룸을 이용한 일시정지 구현

[에뚜(ssss4610)]

게임메이커 스튜디오 2에서 일시정지 UI를 구현하는 방법이 여럿 있는데,

일반적으로 쓰이는 방법으로는, 모든 오브젝트와 스프라이트 비활성화 후, Draw GUI 이벤트로 UI를 그리는 방법이 있지만, 이런저런 불편한 점이 많아

그래서 나는 일시정지 때, 현재 화면을 캡쳐한 후, 별도의 일시정지용 룸으로 이동한 후에, 룸 배경에 캡쳐한 이미지를 draw하는 방법을 이용하고 있어

별도의 룸에, 오브젝트 기반의 UI를 배치하면 되서, draw 기반 UI에 비해 UI 배치가 압도적으로 쉽고,

한번 함수를 잘 짜두면, 일시정지가 필요한 여러 룸(설정, 게임 설명, 업적 등)을 2번 작업할 필요 없이 쉽게 만들 수 있다는 장점이 있다.

실제 작동하는 모습

스크립트

게임 시작 시 몇개의 글로벌 변수를 미리 선언해줘야 함

global.roomBuffer => 일시정지 끝나고 돌아갈 원래 룸의 id 저장할 변수

global.screenBuffer => 캡쳐한 게임 화면을 버퍼 형태로 저장할 변수

핵심 함수는 총 3개로, 기능은 다음과 같다

- sc_goto_pause_room(_room)

인게임 룸의 게임 컨트롤 오브젝트[그러니까 매니저 오브젝트]에서, 일시정지가 필요할 때 호출하는 함수

매개변수에는 이동하고자 할 일시정지용 룸을 입력

현재 게임 화면을 캡쳐한 후 global.screenBuffer에 버퍼 형태로 저장 후, 매개변수로 입력된 룸으로 이동하는 기능

- sc_pause_room_control_create()

일시정지용 룸의 컨트롤 오브젝트의 create 이벤트에서 호출하는 함수

필요한 변수 선언용

- sc_pause_room_control_draw()

일시정지용 룸의 컨트롤 오브젝트의 draw 이벤트에서 호출하는 함수

global.screenBuffer 버퍼에서 서피스를 받아온 후, 화면에 draw하는 기능

여기서 캡쳐한 화면을 바로 글로벌 변수에 서피스 형태로 저장하지 않고, 버퍼에 저장하는 이유는

창모드를 지원하는 게임에서, 창 크기를 변경하면 서피스가 날아가는 문제가 있기 때문..

뭐, 적어도 내가 저 코드 만들 땐 그랬음

일시정지 룸에서 원래 룸으로 돌아갈 땐 그냥

room_goto(global.roomBuffer) 써주면 된다.

원래 룸에 돌아간 후 room_persistent = false 잊지 말고 넣고

이하 복붙용 텍스트

function sc_goto_pause_room(_room) //일시정지가 필요할 때 호출할 함수

{

room_persistent = true; //룸 현재 상태 저장하도록 내장 변수 설정

global.roomBuffer = room; //일시정지 해제 때 돌아올 룸의 ID값 저장

var _cam_width = 1920; //카메라 너비

var _cam_height = 1080; //카메라 높이

if (buffer_exists(global.screenBuffer)) buffer_delete(global.screenBuffer); //예외처리, 이전 버퍼가 남아있으면 버퍼 삭제

global.screenBuffer = buffer_create(_cam_width * _cam_height * 4, buffer_grow, 1); //버퍼 생성 및 크기 설정

var _surf = surface_create(_cam_width, _cam_height); //서피스 생성

surface_copy(_surf,0,0,application_surface); //현재 화면을 서피스에 붙여넣기

buffer_get_surface(global.screenBuffer, _surf, 0); //버퍼에 서피스를 붙여넣기

surface_free(_surf); //임시 서피스 제거

room_goto(_room); //룸 이동

}

function sc_pause_room_control_create() //일시정지용 룸의 컨트롤 오브젝트 create 이벤트에서 호출

{

surf = -1; //서피스

}

function sc_pause_room_control_draw() //일시정지용 룸의 컨트롤 오브젝트 draw 이벤트에서 호출

{

var _cam_width = 1920; //카메라 너비

var _cam_height = 1080; //카메라 높이

if (!surface_exists(surf)) //서피스가 없을 때

{

surf = surface_create(_cam_width, _cam_height); //서피스 생성

buffer_set_surface(global.screenBuffer, surf, 0); //버퍼에 저장된 값을 서피스에 붙여넣기

}

draw_surface(surf, 0, 0); //서피스 그리기, 뒤에 0, 0은 좌표로, 게임이 가변 해상도라면 알아서 조정하기

}

[ㅆㅇㅆ(124.216)]

코드 왤케 잘짜 완장 ㄷㄷ

[에뚜(ssss4610)]

[얀테이(lose7560)]

[에뚜(ssss4610)]

[ㅐㅐㅋㄷ(ooze86)]

천 재

[에뚜(ssss4610)]

[만두두(aksenen)]

와우 코드까지 퇴근하고 자세히 봐야겠다

[에뚜(ssss4610)]

[카퍠인(happys96)]

[에뚜(ssss4610)]

[ㅇㅇ 1(61.72)]

일시정지창 왤케 까리함

[에뚜(ssss4610)]

[해당 댓글은 삭제되었습니다.]

해당 댓글은 삭제되었습니다.

[에뚜(ssss4610)]

[ㅇㅇ 2(121.190)]

오오 이거 대박이다

[에뚜(ssss4610)]